Написать программу Используя тип запись и массив Type data=record Day:integer; Mounth:...

Question

Написать программу
Используя тип запись и массив
Type data=record
Day:integer;
Mounth: integer;
Year: integer;
End;
Var
A: array[1..100] of data;
В семье Ивановых оба ребенка учатся в школе. Мальчик в 5, а девочка в 1 классе. Родительские собрания 5 класса проводятся по последним пятницам, а 1 класса по последним средам месяца в 18:00. Отец и мать этого семейства ведут свое дело. Отец работает до 20:00 по нечетным дням месяца, а мать до 20:00 по четным дням месяца. В другие дни каждый из родителей заканчивает работу в 17:00. Выведите в файл father.txt даты родительских собраний для отца, а в файл mother.txt для матери на 2015-2016 учебный год с указанием класс который они должны посетить.
Pascal abc

Comments

Задача, действительно, немного странная, но определить то, что требуется сделать, вполне можно. Есть неясности с тем, что считать исходными данными. Например, задавать ли все нужные среды и пятницы явным образом или вычислять. Структура дата в паскале есть, но в учебных целях её вполне можно и переопределить в своей программе.

---

Дело в том, что тут все надумано. Если писать в файл, то массив не нужен, а нужна запись, у которой структура совпадает с той, которая должна быть в массиве. Но и это нужно лишь если файл не текстовый. Представление даты в виде трех полей в классическом Паскале вообще ничего не дает, кроме необходимости указывать лишние квалификаторы, потому что Паскаль не умеет работать с целыми записями, как с переменными.

---

Да и массив не нужен, если обмен с файлом.

---

Со всем соглашусь. Но отмечу, что Ваша точка зрения - это точка зрения профессионала. Для учебных задач, в частности для изучения записей и файлов, эта задача вполне подойдет. Здесь, конечно, более интересна алгоритмическая часть - вычисление последних сред и пятниц. Если вспомнить задачу про падающий самолет, то эта мне гораздо больше нравится. )

---

Вот эта алгоритмическая часть:function DOW(Dat:Date):integer;{ день недели по дате. 0-Вс. 1-Пн, .... 7-Сб }var a,y,m:integer;begin With Dat do begin a:=(14 - month) div 12; y:=Year-a; m:=month+12*a-2; DOW:=(7000+(day+y+y div 4-y div 100+y div 400+(31*m) div 12)) mod 7 endend;

---

А дальше берем массив из 12 элементов, содержащий количество дней в каждом месяце году (с поправкой 28/29) на високосный год) и вычисляем номер последнего дня в месяце. Далее простой сдвиг по кольцу из чисел 0...6 на 3й или 5й день, который даст номер дня в месяце для последней среды и пятницы.

---

Но нигде тут фактически не нужны массивы и структуры указанного вида.

---

Я не могу придумать, зачем нужен массив А из дат, тем более, из ста дат. Девять учебных месяцев и даже если там хранить последнюю неделю каждого месяца, это все равно 7х9=63. Но и этого абсолютно не нужно. Максимум - хранить дату последней среды и последней пятницы - это 18 элементов.

---

!!! Один только вопрос - почему 7000?

---

Как-то даже неудобно после Ваших программ свои здесь писать.

Answer 1

// PascalABC.NET 3.0, сборка 1088
const
  nDay:array[1..12] of integer=(31,28,31,30,31,30,31,31,30,31,30,31);
type
  Date=record
    Day,Month,Year:integer
  end;
 
function DOW(Dat:Date):integer;
// день недели по дате. 0-Вс. 1-Пн, .... 7-Сб
var
  a,y,m:integer;
begin
  With Dat do begin
    a:=(14 - month) div 12;
    y:=Year-a;
    m:=month+12*a-2;
    DOW:=(7000+(day+y+y div 4-y div 100+y div 400+(31*m) div 12)) mod 7
    end
end;

procedure DMY2Date(d,m,y:integer; var data:Date);
// Преобразует к дате заданные день, месяц и год
begin
  data.Day:=d; data.Month:=m; data.Year:=y
end;

procedure LastDays(month,year:integer; var Wd,Fr:Date);
// даты последней среды (Wd) и пятницы (Fr) для месяца в году }
var
  LastDay:Date;
  n:integer;
begin
  n:=nDay[month];
  if (month=2) and (year mod 4 = 0) then Inc(n);
  DMY2Date(n,month,year,LastDay);
  n:=DOW(LastDay); // номер последнего дня недели
  Wd.Month:=month; Wd.Year:=year;
  if n<3 then Wd.Day:=LastDay.Day-(n+4)<br>  else
    if n=3 then Wd.Day:=LastDay.Day
    else Wd.Day:=LastDay.Day+3-n;
  Fr.Month:=month; Fr.Year:=year;
  if n<5 then Fr.Day:=LastDay.Day-(n+2)<br>  else
    if n=3 then Fr.Day:=LastDay.Day
    else Fr.Day:=LastDay.Day-1
end;

var
  Wd,Fr:Date;
  ff,mf:Text;
  m:integer;
begin
  Assign(ff,'father.txt'); Rewrite(ff);
  Assign(mf,'mother.txt'); Rewrite(mf);
  // Сентябрь-декабрь 2015 года
  for m:=9 to 12 do begin
    LastDays(m,2015,Wd,Fr);
    if Odd(Wd.Day) then Writeln(mf,Wd.Day,'.',m,'.2015 - 1 класс')
    else Writeln(ff,Wd.Day,'.',m,'.2015 - 1 класс');
    if Odd(Fr.Day) then Writeln(mf,Fr.Day,'.',m,'.2015 - 5 класс')
    else Writeln(ff,Fr.Day,'.',m,'.2015 - 5 класс')
  end;
  // Январь - май 2016 года
  for m:=1 to 5 do begin
    LastDays(m,2016,Wd,Fr);
    if Odd(Wd.Day) then Writeln(mf,Wd.Day,'.',m,'.2016 - 1 класс')
    else Writeln(ff,Wd.Day,'.',m,'.2016 - 1 класс');
    if Odd(Fr.Day) then Writeln(mf,Fr.Day,'.',m,'.2016 - 5 класс')
    else Writeln(ff,Fr.Day,'.',m,'.2016 - 5 класс')
  end;
  Close(ff); Close(mf)
end.

Содержимое выходных файлов:
father.txt
30.9.2015 - 1 класс
28.10.2015 - 1 класс
30.10.2015 - 5 класс
30.12.2015 - 1 класс
24.2.2016 - 1 класс
26.2.2016 - 5 класс
30.3.2016 - 1 класс

mother.txt
25.9.2015 - 5 класс
25.11.2015 - 1 класс
27.11.2015 - 5 класс
25.12.2015 - 5 класс
27.1.2016 - 1 класс
29.1.2016 - 5 класс
25.3.2016 - 5 класс
27.4.2016 - 1 класс
29.4.2016 - 5 класс
25.5.2016 - 1 класс
27.5.2016 - 5 класс

Answer 2

В прилагаемом файле приведен пример программы для решения задачи и содержимое полученных файлов. В программе дата последней среды и последней пятницы сентября 2015 г. задается явно, остальные среды и пятницы вычисляются. При желании можно начать вычисления с 1 января, например, или с 1 сентября. Получится немного длиннее.

---

Скачать вложение Текст (TXT)